VB.Net Program to Find a Function Minimum

Using the Hooke-Jeeves Directional Search Method

by Namir Shammas

The following program calculates the minimum point of a multi-variable function using the Hooke-Jeeves directional search method.

Click here to download a ZIP file containing the project files for this program.

The program prompts you to either use the predefined default input values or to enter the following for each variable:

1. Guess for the minimum point.

2. Initial search step value.

3. The minimum search step value.

In case you choose the default input values, the program displays these values and proceeds to find the optimum point. In the case you select being prompted, the program displays the name of each input variable along with its default value. You can then either enter a new value or simply press Enter to use the default value. This approach allows you to quickly and efficiently change only a few input values if you so desire.

The program displays the following final results:

1. The coordinates of the minimum value.

2. The minimum function value.

3. The number of iterations

The current code finds the minimum for the following function:

f(x1,x2) = x1 - x2 + 2 * x1 ^ 2 + 2 * x1 * x2 + x2 ^ 2

Using, for each variable, an initial value of 0, initial step size of 0.1, minimum step size of 1e-7, and using a function tolerance of 1e-7. Here is the sample console screen:

Here is the listing for the main module. The module contains several test functions:

Module Module1

  Sub Main()
    Dim nNumVars As Integer = 2
    Dim fX() As Double = {0, 0}
    Dim fParam() As Double = {0, 0}
    Dim fStepSize() As Double = {0.1, 0.1}
    Dim fMinStepSize() As Double = {0.0000001, 0.0000001}
    Dim nIter As Integer = 0
    Dim fEpsFx As Double = 0.0000001
    Dim I As Integer
    Dim fBestF
    Dim sAnswer As String
    Dim oOpt As CHookJeevesSearch1
    Dim MyFx As MyFxDelegate = AddressOf Fx3
    Dim SayFx As SayFxDelegate = AddressOf SayFx3

    oOpt = New CHookJeevesSearch1

    Console.WriteLine("Hooke-Jeeves Search Optimization")
    Console.WriteLine("Finding the minimum of function:")
    Console.WriteLine(SayFx())
    Console.Write("Use default input values? (Y/N) ")
    sAnswer = Console.ReadLine()
    If sAnswer.ToUpper() = "Y" Then
      For I = 0 To nNumVars - 1
        Console.WriteLine("X({0}) = {1}", I + 1, fX(I))
        Console.WriteLine("Step size({0}) = {1}", I + 1, fStepSize(I))
        Console.WriteLine("Min step Size ({0}) = {1}", I + 1, fMinStepSize(I))
      Next
      Console.WriteLine("Function tolerance = {0}", fEpsFx)
    Else
      For I = 0 To nNumVars - 1
        fX(I) = GetIndexedDblInput("X", I + 1, fX(I))
        fStepSize(I) = GetIndexedDblInput("Step size", I + 1, fStepSize(I))
        fMinStepSize(I) = GetIndexedDblInput("Min step size", I + 1, fMinStepSize(I))
      Next
      fEpsFx = GetDblInput("Function tolerance", fEpsFx)
    End If

    Console.WriteLine("******** FINAL RESULTS *************")
    fBestF = oOpt.CalcOptim(nNumVars, fX, fParam, fStepSize, fMinStepSize, fEpsFx, nIter, MyFx)
    Console.WriteLine("Optimum at")
    For I = 0 To nNumVars - 1
      Console.WriteLine("X({0}) = {1}", I + 1, fX(I))
    Next
    Console.WriteLine("Function value = {0}", fBestF)
    Console.WriteLine("Number of iterations = {0}", nIter)
    Console.WriteLine()
    Console.Write("Press Enter to end the program ...")
    Console.ReadLine()
  End Sub

  Function GetDblInput(ByVal sPrompt As String, ByVal fDefInput As Double) As Double
    Dim sInput As String

    Console.Write("{0}? ({1}): ", sPrompt, fDefInput)
    sInput = Console.ReadLine()
    If sInput.Trim().Length > 0 Then
      Return Double.Parse(sInput)
    Else
      Return fDefInput
    End If
  End Function

  Function GetIntInput(ByVal sPrompt As String, ByVal nDefInput As Integer) As Integer
    Dim sInput As String

    Console.Write("{0}? ({1}): ", sPrompt, nDefInput)
    sInput = Console.ReadLine()
    If sInput.Trim().Length > 0 Then
      Return Double.Parse(sInput)
    Else
      Return nDefInput
    End If
  End Function

  Function GetIndexedDblInput(ByVal sPrompt As String, ByVal nIndex As Integer, ByVal fDefInput As Double) As Double
    Dim sInput As String

    Console.Write("{0}({1})? ({2}): ", sPrompt, nIndex, fDefInput)
    sInput = Console.ReadLine()
    If sInput.Trim().Length > 0 Then
      Return Double.Parse(sInput)
    Else
      Return fDefInput
    End If
  End Function

  Function GetIndexedIntInput(ByVal sPrompt As String, ByVal nIndex As Integer, ByVal nDefInput As Integer) As Integer
    Dim sInput As String

    Console.Write("{0}({1})? ({2}): ", sPrompt, nIndex, nDefInput)
    sInput = Console.ReadLine()
    If sInput.Trim().Length > 0 Then
      Return Double.Parse(sInput)
    Else
      Return nDefInput
    End If
  End Function

  Function SayFx1() As String
    Return "F(X) = 10 + (X(1) - 2) ^ 2 + (X(2) + 5) ^ 2"
  End Function

  Function Fx1(ByVal N As Integer, ByRef X() As Double, ByRef fParam() As Double) As Double
    Return 10 + (X(0) - 2) ^ 2 + (X(1) + 5) ^ 2
  End Function

  Function SayFx2() As String
    Return "F(X) = 100 * (X(1) - X(2) ^ 2) ^ 2 + (X(2) - 1) ^ 2"
  End Function

  Function Fx2(ByVal N As Integer, ByRef X() As Double, ByRef fParam() As Double) As Double
    Return 100 * (X(0) - X(1) ^ 2) ^ 2 + (X(1) - 1) ^ 2
  End Function

  Function SayFx3() As String
    Return "F(X) = X(1) - X(2) + 2 * X(1) ^ 2 + 2 * X(1) * X(2) + X(2) ^ 2"
  End Function

  Function Fx3(ByVal N As Integer, ByRef X() As Double, ByRef fParam() As Double) As Double
    Return X(0) - X(1) + 2 * X(0) ^ 2 + 2 * X(0) * X(1) + X(1) ^ 2
  End Function

  ' X(0) - X(1) + 2 * X(0) ^ 2 + 2 * X(0) * X(1) + X(1) ^ 2
End Module

Notice that the user-defined functions have accompanying helper functions to display the mathematical expression of the function being optimized. For example, function Fx1 has the helper function SayFx1 to list the function optimized in Fx1. Please observe the following rules::

When you add new user-defined functions to optimize, you must also add an accompanying helper function that states the function mathematical make up.
When you edit an existing user-defined functions to optimize, you must also edit its accompanying helper function to reflect the changes you make in the function mathematical make up
When you select a new user-defined function you must alter both variables MyFx, and SayFx to specify the new function and its accompanying helper function.

The program uses the following class to optimize the objective function:

Public Delegate Function MyFxDelegate(ByVal nNumVars As Integer, ByRef fX() As Double, ByRef fParam() As Double) As Double
Public Delegate Function SayFxDelegate() As String

Public Class CHookJeevesSearch1
  Dim m_MyFx As MyFxDelegate

  Protected Function MyFxEx(ByVal nNumVars As Integer, _
                ByRef fX() As Double, ByRef fParam() As Double, _
                ByRef fDeltaX() As Double, ByVal fLambda As Double) As Double
    Dim I As Integer

    Dim fXX(nNumVars) As Double

    For I = 0 To nNumVars - 1
      fXX(I) = fX(I) + fLambda * fDeltaX(I)
    Next I

    MyFxEx = m_MyFx(nNumVars, fXX, fParam)
  End Function

  Protected Function LinSearch_DirectSearch(ByVal nNumVars As Integer, ByRef fX() As Double, ByRef fParam() As Double, _
          ByRef fLambda As Double, ByRef fDeltaX() As Double, ByVal fInitStep As Double, ByVal fMinStep As Double) As Boolean
    Dim F1, F2 As Double

    F1 = MyFxEx(nNumVars, fX, fParam, fDeltaX, fLambda)

    Do
      F2 = MyFxEx(nNumVars, fX, fParam, fDeltaX, fLambda + fInitStep)
      If F2 < F1 Then
        F1 = F2
        fLambda += fInitStep
      Else
        F2 = MyFxEx(nNumVars, fX, fParam, fDeltaX, fLambda - fInitStep)
        If F2 < F1 Then
          F1 = F2
          fLambda -= fInitStep
        Else
          ' reduce search step size
          fInitStep /= 10
        End If
      End If
    Loop Until fInitStep < fMinStep

    Return True

  End Function

  Public Function CalcOptim(ByVal nNumVars As Integer, ByRef fX() As Double, ByRef fParam() As Double, _
                  ByRef fStepSize() As Double, ByRef fMinStepSize() As Double, ByVal fEpsFx As Double, _
                  ByRef nIter As Integer, ByVal MyFx As MyFxDelegate) As Double
    Dim I As Integer
    Dim fXnew(nNumVars) As Double
    Dim fDeltaX(nNumVars) As Double
    Dim F As Double, fXX As Double, fLambda As Double
    Dim fBestF, fLastBestF As Double
    Dim bStop, bMadeAnyMove As Boolean, bMoved(nNumVars) As Boolean

    m_MyFx = MyFx

    For I = 0 To nNumVars - 1
      fXnew(I) = fX(I)
    Next
    ' calculate function value at initial point
    fBestF = MyFx(nNumVars, fXnew, fParam)
    fLastBestF = 100 * fBestF + 100

    nIter = 1
    Do

      nIter += 1

      For I = 0 To nNumVars - 1
        fX(I) = fXnew(I)
      Next I

      For I = 0 To nNumVars - 1
        bMoved(I) = False
        Do
          fXX = fXnew(I)
          fXnew(I) = fXX + fStepSize(I)
          F = MyFx(nNumVars, fXnew, fParam)
          If F < fBestF Then
            fBestF = F
            bMoved(I) = True
          Else
            fXnew(I) = fXX - fStepSize(I)
            F = MyFx(nNumVars, fXnew, fParam)
            If F < fBestF Then
              fBestF = F
              bMoved(I) = True
            Else
              fXnew(I) = fXX
              Exit Do
            End If
          End If
        Loop
      Next I

      ' moved in any direction?
      bMadeAnyMove = True
      For I = 0 To nNumVars - 1
        If Not bMoved(I) Then
          bMadeAnyMove = False
          Exit For
        End If
      Next I

      If bMadeAnyMove Then
        For I = 0 To nNumVars - 1
          fDeltaX(I) = fXnew(I) - fX(I)
        Next I

        fLambda = 0
        If LinSearch_DirectSearch(nNumVars, fX, fParam, fLambda, fDeltaX, 0.1, 0.0001) Then
          For I = 0 To nNumVars - 1
            fXnew(I) = fX(I) + fLambda * fDeltaX(I)
          Next I
        End If
      End If
      fBestF = MyFx(nNumVars, fXnew, fParam)

      ' reduce the step size for the dimensions that had no moves
      For I = 0 To nNumVars - 1
        If Not bMoved(I) Then fStepSize(I) /= 2
      Next I

      ' test function value convergence
      If Math.Abs(fBestF - fLastBestF) < fEpsFx Then Exit Do

      fLastBestF = fBestF

      bStop = True
      For I = 0 To nNumVars - 1
        If fStepSize(I) >= fMinStepSize(I) Then
          bStop = False
          Exit For
        End If
      Next I

    Loop Until bStop

    For I = 0 To nNumVars - 1
      fX(I) = fXnew(I)
    Next I

    Return fBestF

  End Function
End Class

BACK